Membaca Data RFID RC522 Mifare dengan Arduino

RFID, sesuai namanya Radio Frequency Identitification, adalah identitas unik yang dapat dibaca melalui frekuensi radio. Karena melalui gelombang radio (RF), maka data ditransfer secara wireless, artinya antara RFID tag/card dengan RFID reader tidak perlu bersinggungan/menempel. Cukup didekatkan sekitar 1-5 cm, maka kartu RFID dapat dibaca oleh RFID reader.

RFID yang kita bicarakan adalah RFID yang bertipe pasif. Artinya kartu RFID tidak memiliki catu daya sendiri. Kartu RFID model ini mendapatkan catu daya dari RFID reader yang didekatkan padanya secara wireless. Dengan demikian RFID tipe pasif hanya dapat digunakan untuk jarak pendek (maksimal 5 cm). [AdSense-A]

Catatan: dalam perkembangannya, muncul RFID tag/card bertipe aktif yang memiliki catu daya sendiri. Untuk tipe RFID seperti ini dapat dibaca lebih jauh jaraknya (> 1 m), tergantung dari power level dan frekuensi yang digunakan.

Sekilas RFID RC522 Mifare

RFID RC522 adalah modul RFID produk dari NXP. Modul ini bekerja di frekuensi 13,56 MHz. Harganya relatif murah, di bawah 25 ribu. Bisa di beli di toko online RAFTECH. Modul ini memiliki beberapa pilihan komunikasi dengan controller-nya, yakni SPI, I2C maupun UART. Tinggal dipilih mana yang cocok dengan sistem Anda saat ini. Kalau misalnya pin Arduino banyak yang tidak terpakai, bisa pakai protocol SPI (setidaknya dibutuhkan 5 pin untuk bekerja dengan SPI), atau kalau ingin menghemat pin bisa pakai protokol I2C/UART (hanya butuh 2 pin). Hanya perlu diingat kalau Anda menggunakan Arduino Uno yang hanya memiliki 1 port UART, tentunya Anda harus berpikir ulang menggunakan protokol UART untuk mengendalikan modul RC522 ini (biasanya port UART Arduino Uno digunakan untuk debug program)

Catatan : SPI = Serial Peripheral Interface, I2C = Inter-Integrated Circuit, UART = Universal Asynchronous Receiver Transmitter). SPI dan I2C (atau disebut juga IIC) merupakan protokol serial sinkron, sedangkan UART merupakan serial asinkron

Spesifikasi modul RFID RC522

Tegangan : DC 3.3V
Arus : 13—26mA (idle 10-13mA, sleep : idle:80uA, Peak : 30mA)
Frequensi kerja: 13.56 MHz
Supported Cards: mifare1 S50, mifare1 S70, mifare UltraLight, mifare Pro, mifare Desfire
Dimensi modul : 40 mm × 60 mm
Ambient operating temperature: – 20-80 degrees centigrade
Ambient storage temperature: – 40-85 degrees centigrade
Ambient relative humidity: 5%—95%
Data Transfer Rate (SPI): Max. 10Mbit / s

Konfigurasi RFID RC522 Mifare dengan Arduino

Untuk membaca data RFID RC522 mifare dengan Arduino, koneksikan modul tersebut dengan Arduino sebagai berikut. Pada tutorial ini saya akan mencontohkan bagaimana berkomunikasi dengan modul RC522 menggunakan protokol SPI. Berikut ini konfigurasi hardware-nya.

Gambar Rangkaian Arduino – RFID RC522

Berikut ini adalah rangkaian Arduino – module RFID RC522 Mifare menggunakan protokol SPI dalam berkomunikasi. Perhatikan bahwa modul ini menggunakan tegangan 3,3V ya, jangan sampai salah dikoneksikan ke 5V Arduino karena bisa menyebabkan kerusakan modul.

Sketch Arduino – RFID RC522 Mifare

Setelah koneksi hardware sudah dirangkai, sekarang tinggal meng-upload sketch handler untuk modul RFID RC522. Untuk mudahnya Anda dapat men-download library khusus untuk modul ini disini. Tambahkan library ini ke Arduino IDE Anda. Caranya bisa disimak di sini. Di dalam library tersebut juga ada contoh source code-nya, jadi bisa dipelajari untuk kebutuhan custom Anda. Untuk mencoba module RFID Anda, silahkan di-upload sketch ‘ReadNUID.ino’ di menu File-examples-MFRC522-ReadNUID. Sketch-nya adalah sbb :

#include <SPI.h>
#include <MFRC522.h>

#define SS_PIN 10
#define RST_PIN 9

MFRC522 rfid(SS_PIN, RST_PIN);
MFRC522::MIFARE_Key key;

byte nuidPICC[4];

void setup() {
  Serial.begin(9600);
  SPI.begin(); // Init SPI bus
  rfid.PCD_Init(); // Init MFRC522
  for (byte i = 0; i < 6; i++) {
    key.keyByte[i] = 0xFF;
  }

  Serial.println(F("Kode NUID RFID"));
  printHex(key.keyByte, MFRC522::MF_KEY_SIZE);
}

void loop() {
  // cek kartu RFID baru
  if ( ! rfid.PICC_IsNewCardPresent())
    return;
  // kalo sudah pernah terbaca …
  if ( ! rfid.PICC_ReadCardSerial())
    return;

  Serial.print(F("Tipe PICC : "));
  MFRC522::PICC_Type piccType = rfid.PICC_GetType(rfid.uid.sak);
  Serial.println(rfid.PICC_GetTypeName(piccType));
  // cek PICC
  if (piccType != MFRC522::PICC_TYPE_MIFARE_MINI && 
    piccType != MFRC522::PICC_TYPE_MIFARE_1K &&
    piccType != MFRC522::PICC_TYPE_MIFARE_4K) {
    Serial.println(F("kartu Anda bukan MIFARE Classic..."));
    return;
  }

  if (rfid.uid.uidByte[0] != nuidPICC[0] ||
    rfid.uid.uidByte[1] != nuidPICC[1] ||
    rfid.uid.uidByte[2] != nuidPICC[2] ||
    rfid.uid.uidByte[3] != nuidPICC[3] ) {
    Serial.println(F("kartu RFID baru terdeteksi"));
    // Store NUID into nuidPICC array
    for (byte i = 0; i < 4; i++) {
      nuidPICC[i] = rfid.uid.uidByte[i];
    }

    Serial.println(F("The NUID tag is:"));
    Serial.print(F("In hex: "));
    printHex(rfid.uid.uidByte, rfid.uid.size);
    Serial.println();
    Serial.print(F("In dec: "));
    printDec(rfid.uid.uidByte, rfid.uid.size);
    Serial.println();
  }

  else Serial.println(F("Card read previously."));
  // Halt PICC
  rfid.PICC_HaltA();
  // Stop encryption on PCD
  rfid.PCD_StopCrypto1();
}

// print kode RFID dalam bentu heksa
void printHex(byte *buffer, byte bufferSize) {
  for (byte i = 0; i < bufferSize; i++) {
    Serial.print(buffer[i] < 0x10 ? " 0" : " ");
    Serial.print(buffer[i], HEX);
  }
}

// print kode RFID dalam bentuk desimal
void printDec(byte *buffer, byte bufferSize) {
  for (byte i = 0; i < bufferSize; i++) {
    Serial.print(buffer[i] < 0x10 ? " 0" : " ");
    Serial.print(buffer[i], DEC);
  }
}

Coba upload script di atas, dan aktifkan jendela Serial Monitor Anda untuk mencoba melihat data-data RFID dalam kartu RFID Mifare classic yang diikutkan dalam paket pembelian. Teknologi RFID ini biasanya digunakan akses gedung perkantoran yang hanya mengijinkan karyawan yang terdaftar atau untuk tracking asset management. Selamat mencoba. Jika membutuhkan RFID module ini bisa dibeli di toko saya : https://www.tokopedia.com/raftech/rfid-mifare-rc522-readerwriter-module-untuk-arduino-raspberry-pi. Hanya 23.500 🙂 [AdSense-A]